\ Opgave 7 (Hillier and Lieberman, exercise 12)

maximize
70 x1 + 60 x2 + 90 x3 + 80 x4 - 50000 d1 - 40000 d2 - 70000 d3 - 60000 d4


subject to

\ ----------------------------------------------------------------------- 
\ Indikatorvariable: di = 1  <=>  xi >= 0.01, i=1,..,4 
\ Indikatorvariable bindes sammen med produktionsvariable */

x1 - 2000 d1 <= 0
x2 - 2000 d2 <= 0
x3 - 2000 d3 <= 0
x4 - 2000 d4 <= 0

x1 - 0.01 d1 >= 0
x2 - 0.01 d2 >= 0
x3 - 0.01 d3 >= 0
x4 - 0.01 d4 >= 0


\ ----------------------------------------------------------------------- 
\ Hoejst to produkter kan produceres 

d1 + d2 + d3 + d4 <= 2


\ ----------------------------------------------------------------------- 
\ Produkt (3 eller 4) kan produceres hvis produkt (1 eller 2) 

d3 - d1 - d2 <= 0
d4 - d1 - d2 <= 0

\ ----------------------------------------------------------------------- 
\ Enten 5x1 + 3x2 + 6x3 + 4x4 <= 6000 eller 4x1 + 6x2 + 3x3 + 5x4 <= 6000 

\ Indikatorvariable  
\ da = 1  =>  5x1 + 3x2 + 6x3 + 4x4 <= 6000 
\ db = 1  =>  4x1 + 6x2 + 3x3 + 5x4 <= 6000 

5 x1 + 3 x2 + 6 x3 + 4 x4 + 30000 da <= 36000
4 x1 + 6 x2 + 3 x3 + 5 x4 + 30000 db <= 36000

\ mindst en af betingelserne er overholdt 

da + db >= 1


\ ----------------------------------------------------------------------- 
\ Begraensninger paa variable 

d1 <= 1
d2 <= 1
d3 <= 1
d4 <= 1

da <= 1
db <= 1

x1 <= 2000
x2 <= 2000
x3 <= 2000
x4 <= 2000

\ Heltalsvariable 

binary

d1 d2 d3 d4 da db

end